# Maintainer: Sl@ny <webmaster [at] slany [dot] work>
pkgname=drone
pkgver=2.0.0
pkgrel=1
pkgdesc="Drone is a Continuous Delivery platform built on Docker, written in Go - Free enterprise variant"
arch=('x86_64')
url="https://drone.io"
license=('Apache')
makedepends=('go' 'git' 'gcc')
backup=('etc/drone/server')
source=(git+https://github.com/drone/drone.git#tag=v$pkgver
        'drone.service'
        'server.conf')
sha256sums=('SKIP'
            '3cd219b1c5611b9ff4211d4837dff11228d9a491cd41d21f4c60af77c8c21d5c'
            '2b8957cd6b9f9ee6e8d831f58b0ef3fac2170a56f6259884ec7d30c3ba38c73a')

build() {
    cd "$srcdir/$pkgname"
    go build -a -v -trimpath -buildmode=pie -mod=readonly -tags "nolimit" -ldflags '-w -s' ./cmd/drone-server
}

package() {
    cd "$srcdir"

    # binaries
    install -Dm755 "$pkgname/$pkgname"-server "$pkgdir"/usr/bin/"$pkgname"-server

    # license
    install -Dm644 "$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    # service
    install -Dm644 drone.service "$pkgdir/usr/lib/systemd/system/drone.service"

    # config
    install -Dm644 server.conf "$pkgdir/etc/drone/server"
}