# Maintainer: nyyu <mail at nyyu dot dev>

pkgbase=woodpecker
pkgname=(
  'woodpecker-server'
  'woodpecker-agent'
  'woodpecker-cli'
)
pkgver=0.15.0+387+gf0e518a5a
pkgrel=1
pkgdesc="Woodpecker is a community fork of the Drone CI system"
arch=('x86_64')
url="https://woodpecker-ci.org"
license=('Apache')
makedepends=('go' 'git' 'npm')
options=('!lto')
source=(git+https://github.com/woodpecker-ci/woodpecker.git
    'woodpecker-server.service'
    'woodpecker-agent.service'
    'agent.conf'
    'server.conf')
sha256sums=('SKIP'
            '6e22e6939222aaad07311e37a086935ca32dd149c3688b2809db5f55df816516'
            '176d884407b89da3e83cb0b19c506a3fd5ce39a19fb6346e512562ee73e50373'
            '7bc4d8ab05573ff761f001a445207a5a9f533b4cb5cf7c538a45dceceb04d441'
            '71807249f898f323fac434cfa01a7af91bb442d4050ae0c955e400a4bb9edef1')

pkgver() {
  cd "$pkgbase"
  git describe --tags | sed 's/^v//;s/-/+/g'
}

prepare() {
    cd "$pkgbase"

    mkdir -p build-server build-agent build-cli

    go mod download
}

build() {
    cd "$pkgbase"

    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    local COMMON_FLAGS=(
        -trimpath
        -buildmode=pie
        -mod=readonly
        -modcacherw
        -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" -X github.com/woodpecker-ci/woodpecker/version.Version=${pkgver}"
    )

    cd web
    npm install
    npm run build
    cd ..

    go build \
        "${COMMON_FLAGS[@]}" \
        -o build-server \
        ./cmd/server/...

    go build \
        "${COMMON_FLAGS[@]}" \
        -o build-agent \
        ./cmd/agent/...
    
    go build \
        "${COMMON_FLAGS[@]}" \
        -o build-cli \
        ./cmd/cli/...
}

check() {
    cd "$pkgbase"

    go test -v ./...
}

package_woodpecker-server() {

    backup=('etc/woodpecker/server')

    # service
    install -Dm644 woodpecker-server.service "$pkgdir/usr/lib/systemd/system/woodpecker-server.service"
    # config
    install -Dm644 server.conf "$pkgdir/etc/woodpecker/server"

    cd "$pkgbase"
    
    # binary
    install -vDm755 build-server/server "$pkgdir/usr/bin/woodpecker-server"
}


package_woodpecker-agent() {

    backup=('etc/woodpecker/agent')

    # service
    install -Dm644 woodpecker-agent.service "$pkgdir/usr/lib/systemd/system/woodpecker-agent.service"
    # config
    install -Dm644 agent.conf "$pkgdir/etc/woodpecker/agent"

    cd "$pkgbase"

    # binary
    install -vDm755 build-agent/agent "$pkgdir/usr/bin/woodpecker-agent"
}


package_woodpecker-cli() {
    cd "$pkgbase"

    # binary
    install -vDm755 build-cli/cli "$pkgdir/usr/bin/woodpecker"
}