_version=3.38.1
_patch=01

pkgname=nexus-oss
pkgver=${_version}.${_patch}
pkgrel=1
pkgdesc='Nexus 3 Repository OSS'
arch=('any')
url='http://nexus.sonatype.org'
license=("custom:$pkgname")
depends=('java-runtime=11')
replaces=('nexus3')
provides=('nexus3')
backup=("var/lib/$pkgname/etc/nexus.properties"
	"usr/lib/$pkgname/bin/nexus.vmoptions"
)
source=("https://download.sonatype.com/nexus/3/nexus-$_version-$_patch-unix.tar.gz"
	"$pkgname"
	"$pkgname.properties"
	"$pkgname.service"
	"$pkgname.sysusers"
	"$pkgname.tmpfiles"
	"$pkgname.vmoptions"
	"pref_jre.cfg"
)
sha256sums=('2f2b6e7e107e12522fa00de2737defe59837567e16cbec2d0339ba1aa57fdb79'
            'b33fbb8769ac73fe339ea2875a240f308fbd584519f533fba25cf6136eac2dd0'
            'dcdef5614db12f38b3da0b9de1b52fb7fa402af6621a825981c6168a34a6ad9b'
            'bb6d16579712ebb15df948ac395b9095955c12fec9160dd871254836a82c4062'
            '29567e274ffacb06e03580d94685b04aeb7197cd84a14108a347ad5307931be6'
            '939994095f0c5de005a1e36a295bea791a70dadfa32af23b400cbd87be57af9c'
            '176c02ba4299ad818eed75cdaeb42a2d9ffa7332fc74ff30b7c37965e7095df4'
            'd713e29b72522fe4395b6959d27e2a98a24961393e08df7a6b022b1fd77c650d')

package() {
	install -dm755 $pkgdir/usr/lib
	install -dm750 $pkgdir/var/lib/$pkgname

	cp -a $srcdir/nexus-$_version-$_patch $pkgdir/usr/lib/$pkgname
	cp -a $srcdir/sonatype-work/nexus3/orient $pkgdir/var/lib/$pkgname

	pushd $pkgdir/usr/lib/$pkgname
	rm -rf bin/nexus.rc \
		bin/contrib \
		LICENSE.txt
	popd

	install -Dm640 $srcdir/$pkgname.properties $pkgdir/var/lib/$pkgname/etc/nexus.properties

	install -Dm644 $srcdir/nexus-$_version-$_patch/OSS-LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE
	install -Dm755 $srcdir/$pkgname $pkgdir/usr/bin/$pkgname
	install -Dm644 $srcdir/$pkgname.vmoptions $pkgdir/usr/lib/$pkgname/bin/nexus.vmoptions
	install -Dm644 $pkgname.service "$pkgdir/usr/lib/systemd/system/$pkgname.service"
	install -Dm644 $pkgname.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
	install -Dm644 $pkgname.sysusers "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
	install -m644 pref_jre.cfg $pkgdir/usr/lib/$pkgname/.install4j

	chmod -R o-rwx $pkgdir/var/lib/$pkgname
}