aur/pacman/PKGBUILD

# vim: set ts=2 sw=2 et:
# Maintainer: 

pkgname=pacman
pkgver=6.0.1.r0.g0a6fecd0
pkgrel=1
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
url="https://www.archlinux.org/pacman/"
license=('GPL')
groups=('base-devel')
depends=('bash' 'glibc' 'libarchive' 'curl'
         'gpgme' 'pacman-mirrorlist' 'archlinux-keyring')
makedepends=('meson' 'asciidoc' 'doxygen')
checkdepends=('python' 'fakechroot')
optdepends=('perl-locale-gettext: translation support in makepkg-template')
provides=('libalpm.so')
backup=(etc/pacman.conf
        etc/makepkg.conf)
options=('strip' 'debug')
validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD'  # Allan McRae <allan@archlinux.org>
              'B8151B117037781095514CA7BBDFFC92306B1121') # Andrew Gregory (pacman) <andrew@archlinux.org>
source=(git+https://gitlab.archlinux.org/pacman/pacman.git#branch=release/6.0.x
        add-flto-to-LDFLAGS-for-clang.patch
        pacman.conf
        makepkg.conf)
sha256sums=('SKIP'
            '82ff91b85f4c6ceba19f9330437e2a22aabc966c2b9e2a20a53857f98a42c223'
            '4aea8b8dc81188e9f195d0ac887e3a7c85d1be6545fd675f6c160623023d85b5'
            '6c0fca917df610e98e19641d8ac3a9b865fb9e639f811e6f65bbb201c37d3181')


pkgver() {
  cd pacman

  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd pacman
  patch -Np1 -i ../add-flto-to-LDFLAGS-for-clang.patch
}

build() {
  cd pacman

  meson --prefix=/usr \
        --buildtype=plain \
        -Ddoc=enabled \
        -Ddoxygen=enabled \
        -Duse-git-version=true \
        -Dscriptlet-shell=/usr/bin/bash \
        -Dldconfig=/usr/bin/ldconfig \
        build

  meson compile -C build
}

check() {
  cd pacman

  meson test -C build
}

package() {
  cd pacman

  DESTDIR="$pkgdir" meson install -C build

  # install Arch specific stuff
  install -dm755 "$pkgdir/etc"
  install -m644 "$srcdir/pacman.conf" "$pkgdir/etc"
  install -m644 "$srcdir/makepkg.conf" "$pkgdir/etc"
}